rem bf2 server PB screenshots uploader

rem set temp variables
rem only this section should be different on each server
set homedir=C:\
set bf2dir=%userfilespath-notrailingslash%\conf
set ftpuser=bf
set ftppass=bf
set ftpserver=bf.killercreation.co.uk

rem Abort if no PB screenshots exist
if not exist %bf2dir%\pb\svss\*.png goto clean-up
rem rename pb screenshots adding random number
cd %bf2dir%\pb\svss
rem for %%i in (*.png) do ren %%i %date:~-4,4%%date:~-7,2%%date:~-10,2%_%%i
cd %homedir%

rem build ftp commands file
echo open %ftpserver%> bf2_uploader.txt
echo %ftpuser%>> bf2_uploader.txt
echo %ftppass%>> bf2_uploader.txt
echo prompt>> bf2_uploader.txt
echo type binary>> bf2_uploader.txt
echo cd /bc2/pbss/%serverip%/%serverport%>> bf2_uploader.txt
rem select pb screenshots
echo mput %bf2dir%\pb\svss\*.png>> bf2_uploader.txt
echo type ascii>> bf2_uploader.txt
echo mput %bf2dir%\pb\svss\*.htm>> bf2_uploader.txt
echo bye>> bf2_uploader.txt
rem upload all selected files to ftp server
ftp -s:bf2_uploader.txt

rem delete all pb screenshots
del %bf2dir%\pb\svss\*.png /q
del %bf2dir%\pb\svss\pb0*.htm /q

:clean-up
set homedir=
set bf2dir=
set ftpserver=
set ftpuser=
set ftppass=
del bf2_uploader.txt